boo on Conan for making it sound impossible to use
You can't have a slider to adjust it in-game, but you can adjust it until it's what you want, and very easily change it yourself
take that explosion_impulse, unzip it and put it in your add-ons
now all you have to do is adjust the explosion datablock's values until it does what you want
So, load up the game, and you use console to type things like impulseExplosion.camShakeRadius = 50;
you keep changing the values mentioned in the script until it's doing what you want it to do.
When you're done messing around with it, if you've lost track of what you've done so far, you can type impulseExplosion.dump();, scroll up until you see "Member Fields" and the console will show you all the values it currently has. (It will show you a lot of default values which you don't need to write in; just look for the values that you've changed)
Copy all the values you've changed back into the datablock file, and save it.
if you haven't read it already, the script is super readable:
datablock ExplosionData(impulseExplosion)
{
//explosionShape = "";
explosionScale = "1 1 1";
// does the camera shake
shakeCamera = true;
// how often does the camera shake
camShakeFreq = "1.0 1.0 1.0";
// how hard does the camera shake
camShakeAmp = "0.4 0.4 0.4";
// how long does it last in bed
camShakeDuration = 0.5;
// how far does the shake go
camShakeRadius = 20.0;
// make it so it doesn't forget brothers up when used
damageRadius = 0;
radiusDamage = 0;
// don't send people flying and stuff that's annoying
impulseRadius = 0;
impulseForce = 0;
};
// make a projectile because you can't spawn an explosion on it's own
datablock ProjectileData(impulseProjectile)
{
explosion = impulseExplosion;
uiName = "Impulse";
};
Increase camShakeRadius to make it reach farther
camShakeDuration to make it last longer
camShakeFreq to make it shakier
If you want to make more datablocks, just copy the whole thing, paste it below in the same file, rename the datablock names and uiName to something else, and add the values you want.
It's super simple entry-level stuff. Just gotta know it's possible.
datablock ExplosionData(largeImpulseExplosion : impulseExplosion) //this copies every attribute of impulseExplosion unless they're redefined below
{
camShakeRadius = 1000.0; //more or less shakes everyone who is in visible range of the brick it spawns from
camShakeFreq = "10 10 10"; //make the shake shakier
camShakeDuration = 5; //shake it up for a whole five seconds
};
datablock ProjectileData(largeImpulseProjectile)
{
explosion = largeImpulseExplosion;
uiName = "Impulse - large";
};
